Maquina de reciclaje semiautomática

Debido a la cantidad de residuos que genera el ser humano decidimos realizar una máquina que clasifique dichos residuos para poder reciclar de una manera más eficiente. Separando entre plástico, papel y vidrio y depositando cada uno en un apartado diferente.

Objetivos de nuestro proyecto

Crear una maquina transportadora que mueva objetos.

Diseñar un sistema que nos permita la clasificación de los objetos dependiendo de su material.

Organizar y colocar los diferentes elementos de la manera más limpia y clara posible.

---

---

---

Reparto de tareas/ Planificación

Coste de Materiales

Referencia	Coste (total de unidades)
Silicona	3 €
Madera de contrachapado	10 €
Palos de madera	2 €
Tubos de PVC	1,5 €
Goma Eva	1 €
Láser	2 €
Motor	12 €
Servomotores	10 €
Cables	2 €
Pilas 4,5V	6 €
Fotodiodo	0,5 €
Coste total	50 €

---

Hardware

Para mover la cinta hemos conectado un pin digital de Arduino a un transistor una resistencia de 330Ω que funciona como interruptor, también tenemos un diodo que funciona como salvaguarda para no quemar el Arduino ni los cables. Hemos utilizado un mecanismo de engranajes conectado al motor que nos proporciona el torque necesario para que la cinta se mueva a la velocidad adecuada. A su vez tenemos un láser y un fotodiodo que miden si hay un objeto entre ellos y la opacidad de este. El láser está conectado al GND de Arduino y el positivo a la placa puesto que el láser necesita 5V para funcionar.

---

Software

A continuación mostramos el código comentado, explicando lo que hacen las líneas mas relevantes en cada caso.

#include "Servo.h"
#include "LiquidCrystal.h"
#include "IRremote.h"

//Definimos pines analogicos
int pinFotoDiodo = A0;
int pinLaser = A2;

//Definimos pines digitales
int trig = 2;
int echo = 3;
int pinMotor = 4;
int servoMotorPl = 5;
int servoMotorPa = 6;
int receptorIR = 7;


//Definimos variables de control
int valorPHD;
long tiempo;
float d;
float distancia;
int isVidrio;
int umbralPlastico = 850;
int umbralPapel = 100;
int pos = 0;


//Definimos objetos de las clases importadas
LiquidCrystal lcd(12,13, 8, 9, 10, 11);
Servo servoMotorPapel;
Servo servoMotorPlastico;
IRrecv mando(receptorIR);


//Definimos funciones que vamos a utilizar en loop para evitar escribir codigo repetido y modularizar el codigo

//funcion que inicia la cinta y reseta los servomotores
void iniciarSketch() {
  digitalWrite(pinMotor, HIGH);  //poner cinta a correr
  lcd.begin(16, 2);
  servoMotorPapel.write(0);
  servoMotorPlastico.write(0);
}

//funcion que define el movimiento de los servomotores en funcion de cuales sean
void moverServo(int pinServoMotor) {

  if (pinServoMotor == servoMotorPa) {
    for (pos = 0; pos <= 75; pos += 1) {  
      servoMotorPapel.write(pos);  
      delay(10);                   
    }
  } else {
    for (pos = 0; pos <= 75; pos += 1) {  
      servoMotorPlastico.write(pos);  
      delay(10);                      
    }
  }
}

//funcion que lanza un trigger para obtener un pulso en el sensor ultrasonico, lo recibe en echo y retorna la distancia que hay
float obtenerDistancia(){
  //ponemos trig a LOW por si estaba HIGH
  digitalWrite(trig, LOW);
  delayMicroseconds(4);

  //ahora lanzamos el pulso poniendo a HIGH trig esperamos 10 ms y lo ponemos en LOW
  digitalWrite(trig, HIGH);
  delayMicroseconds(10);
  digitalWrite(trig, LOW);

  tiempo = pulseIn(echo, HIGH);  //medimos el tiempo que tarda en volver el pulso, en microsegundos
  
  d = tiempo * 10 / 292/ 2;   //formula que aparece en internet para obtener la distancia en cm
  return d;
}

//funcion que se ejecuta cuando sea un plastico
void isPlastico() {
  //Esta funcion tiene que poner la cinta en marcha de nuevo y mover el servomotor del plastico a su posicion
  //posteriormente se queda a la espera de que el plastico se mueva hasta que caiga al contenedor, tambien tiene que poner
  //antes de mover la cinta en la pantalla que es un plástico

  lcd.write("PLASTICO");         //Escribo plastico
  analogWrite(pinLaser, 0);

  moverServo(servoMotorPl);             //muevo el servomotor
  delay(500);
  digitalWrite(pinMotor, HIGH);  //muevo la cinta
  delay(4500);                         //tiempo que hemos medido que tarda hasta que cae
  for (pos = 75; pos >= 0; pos -= 1) {  
    servoMotorPlastico.write(pos);  
    delay(10);                      
  }                                 //retorno el estado inicial
}

//funcion que se ejecuta cuando sea un papel
void isPapel() {
  //Esta funcion tiene que poner la cinta en marcha de nuevo y mover el servomotor del papel a su posicion
  //posteriormente se queda a la espera de que el papel se mueva hasta que caiga al contenedor, tambien tiene que poner
  //antes de mover la cinta en la pantalla que es un papel

  lcd.write("PAPEL");            //Escribo papel
  //No hace falta que apague el laser porque ya lo he apagado seguro en manual, no puedo llegar a esta funcion si no es desde manual()

  moverServo(servoMotorPa);             //muevo el servomotor
  delay(1000);
  digitalWrite(pinMotor, HIGH);  //muevo la cinta

  delay(5000);                         //tiempo que hemos medido que tarda hasta que cae
  for (pos = 75; pos >= 0; pos -= 1) {  
    servoMotorPapel.write(pos);  
    delay(10);                   
  }                              //retorno el estado inicial
}

void manual() {
  //En esta funcion como no sabemos si es papel o plastico opaco(lata) queremos incluir un mando que cuando detecte que el objeto es opaco
  //tu le des a un boton y digas si es papel o plastico opaco entonces la cinta esta parada
  //y hasta que no se pulse el boton del mando diciendo si es papel, vidrio o plastico no se va a mover
  //Apago el laser antes de ponerme a la espera de que pulsen el boton para no quemar el objeto
  analogWrite(pinLaser, 0);

  while (true) { //esto simula un loop() y dentro lo que hacemos es comprobar cada segundo si se pulsa el mando, saliendo cuando hayamos encontrado el 
  // hexadecimal correspondiente a los botones que pulsamos despues de ejecutar la funcion de cada material
    if (mando.decode()) { 
      //A partir de aqui se ha pulsado el mando o no, y tengo que distinguir si se ha pulsado papel o se ha pulsado plastico
      Serial.println(mando.decodedIRData.decodedRawData, HEX);
      if (mando.decodedIRData.decodedRawData == 0xE916FF00) {         //He pulsado 0 y es papel
        isPapel();                                                    //Si es papel tengo que poner la cinta en marcha apagar el laser
        break;
      } else if (mando.decodedIRData.decodedRawData == 0xF30CFF00) {  //He pulsado 1 y es plastico
        isPlastico();                                                 //Aqui puedo llamar directamente a la funcion isPlatico que lo hace todo
        break;
      }
      delay(1000);
      mando.resume(); //esto da paso a que se vuelva a recibir un valor
    }

  };
  //vuelvo a llamar a resume porque al salir con un break del while no lo llamo
  mando.resume();
}

//no hay funcion cuando sea vidrio porque no hay que hacer nada solo dejar correr la cinta unos segundos hasta que llegue
//el vidrio y escribir por pantalla que hay vidrio 


void setup() {
  Serial.begin(9600);
  
  pinMode(pinMotor, OUTPUT);
  pinMode(pinFotoDiodo, INPUT);
  pinMode(pinLaser, OUTPUT);
  pinMode(trig, OUTPUT);
  pinMode(echo, INPUT);

  servoMotorPapel.attach(servoMotorPa);
  servoMotorPlastico.attach(servoMotorPl);
  mando.enableIRIn();


  //llamamos a funcion iniciarSketch() para que se inicie todo correctamente y evitar escribir mucho codigo en las funciones principales que ejecuta
  //arduino para que sea mas legible
  iniciarSketch();
}

void loop() {  //en el loop queremos encender el laser al principio para detectar un cambio en el valor leido
  delay(1750);
  analogWrite(pinLaser, 255); //encendemos el laser
  delay(250); //Le doy tiempo al laser a encenderse antes de ponerme a medir
  lcd.clear(); //limpiamos lo que habia en la pantalla por si venimos de algun caso 
  while (analogRead(pinFotoDiodo) > umbralPlastico && analogRead(pinFotoDiodo) <= 1023) { //nos ponemos a leer del fotodiodo
    Serial.println(analogRead(pinFotoDiodo)); //Linea para depurar, no es util
    delay(75);
    distancia = obtenerDistancia(); //obtenemos la distancia
    //Serial.print(distancia); Serial.println(" cm"); //Depuracion
    if(distancia <= 6 && analogRead(pinFotoDiodo) > umbralPlastico + 50){
      lcd.write("VIDRIO");
      delay(2500);
      lcd.clear();
    }
  };
  //Paramos la cinta
  valorPHD = analogRead(pinFotoDiodo);
  digitalWrite(pinMotor, LOW);
  delay(500);
  //Aqui pasamos el while si no es igual el valor medido que el que hemos leido al principio
  //O bien es vidrio lo cual seguiria la cinta corriendo y el vidrio se colocaria o bien no ha leido nada
  //Una vez pasemos el while tenemos que distinguir 2 casos, papel(o cualquier objeto opaco) o plástico translúcido

  if (valorPHD <= umbralPapel) {  //Estamos en el caso de papel o un objeto opaco
    Serial.println("MANUAL");
    manual();                                                         //Llamo a las funciones que hacen el trabajo para mantener el loop limpio
  } else if (valorPHD > umbralPapel && valorPHD <= umbralPlastico) {  //Caso de plastico
    Serial.println("PLASTICO");
    isPlastico();  //Llamo a las funciones que hacen el trabajo para mantener el loop limpio
  }
  //Si por lo que sea hemos superado este umbral es que no ha medido bien, por lo que no hariamos nada
  digitalWrite(pinMotor, HIGH);
}

Problemas encontrados y nuestras soluciones